45 lines
1.1 KiB
Haskell
45 lines
1.1 KiB
Haskell
{-|
|
|
Module : Data.Functor.Foldable
|
|
Description : Simplified recursion schemes
|
|
Copyright : (c) Mats Rauhala, 2020
|
|
License : BSD-3-Clause
|
|
Maintainer : mats.rauhala@iki.fi
|
|
Stability : experimental
|
|
Portability : POSIX
|
|
|
|
Simplified recursion schemes, providing only the minimal schemes
|
|
-}
|
|
module Data.Functor.Foldable
|
|
( Fix(..)
|
|
, cata
|
|
, ana
|
|
, hylo
|
|
)
|
|
where
|
|
|
|
import Data.Functor.Classes
|
|
|
|
newtype Fix f = Fix { getFix :: f (Fix f) }
|
|
|
|
instance Show1 f => Show (Fix f) where
|
|
showsPrec d (Fix f) = showString "Fix " . showsPrec1 d f
|
|
|
|
instance Eq1 f => Eq (Fix f) where
|
|
(Fix a) == (Fix b) = liftEq (==) a b
|
|
|
|
-- | Catamorphism or the fold
|
|
--
|
|
-- Fold a recursive structure into a value
|
|
cata :: Functor f => (f a -> a) -> Fix f -> a
|
|
cata f = a where a = f . fmap a . getFix
|
|
|
|
-- | Anamorphism or the unfold
|
|
--
|
|
-- Unfold a seed into a recursive structure
|
|
ana :: Functor f => (a -> f a) -> a -> Fix f
|
|
ana f = a where a = Fix . fmap a . f
|
|
|
|
-- | Combined fold and unfold
|
|
hylo :: (Functor f) => (f a -> a) -> (b -> f b) -> b -> a
|
|
hylo f u = a where a = f . fmap a . u
|