Split Controller.hs into vertical submodules behind umbrella re-export

This commit is contained in:
MasseR committed 2026-09-30 00:07:31 +03:00
1 parent 9e00aeb6a2
commit adce7c8427
13 files changed
+444 -341

No files matched your search

+55
View File
@@ -0,0 +1,55 @@
{-# LANGUAGE Arrows #-}
{-# LANGUAGE GADTs #-}
module HomeAssistant.Controller.Effect
( HASSEff(..)
, HASS
, callService
, callServices
, callServiceDyn
, callServicesDyn
, debug
, traceEvent
, traceValue
) where
import AFRP (Mealy, eff, Event (..), Request)
import Control.Arrow (returnA)
import HomeAssistant.Controller.Service (Service)
data HASSEff a where
CallService :: Request -> Service -> HASSEff ()
CallServices :: Request -> [Service] -> HASSEff ()
Debug :: Show a => a -> HASSEff ()
Trace :: Show a => Request -> a -> HASSEff ()
type HASS a b = Mealy HASSEff a b
callService :: Service -> HASS a ()
callService service = eff (\req _ -> CallService req service)
callServices :: [Service] -> HASS a ()
callServices service = eff (\req _ -> CallServices req service)
callServiceDyn :: (a -> Service) -> HASS a ()
callServiceDyn mkService = eff (\req a -> CallService req (mkService a))
callServicesDyn :: (a -> [Service]) -> HASS a ()
callServicesDyn mkService = eff (\req a -> CallServices req (mkService a))
debug :: Show a => HASS a a
debug = proc x -> do
eff (const Debug) -< x
returnA -< x
traceEvent :: Show a => HASS (Event a) (Event a)
traceEvent = proc ev -> do
case ev of
Event a -> eff Trace -< a
Tick -> returnA -< ()
returnA -< ev
traceValue :: Show a => HASS a a
traceValue = proc x -> do
eff Trace -< x
returnA -< x