Split Controller.hs into vertical submodules behind umbrella re-export
This commit is contained in:
1 parent
9e00aeb6a2
commit
adce7c8427
13 files changed
+444
-341
No files matched your search
@@ -0,0 +1,53 @@
|
||||
{-# LANGUAGE Arrows #-}
|
||||
{-# LANGUAGE OverloadedStrings #-}
|
||||
|
||||
module HomeAssistant.Controller.Light.Observation
|
||||
( LightSnapshot(..)
|
||||
, observedLight
|
||||
, lightBrightnessEvent
|
||||
, lightTemperatureEvent
|
||||
) where
|
||||
|
||||
import AFRP (Event, hold, toEvent, (>>|))
|
||||
import Control.Arrow (arr, returnA)
|
||||
import Control.Category ((>>>), (.))
|
||||
import Control.Lens ((^?))
|
||||
import Data.Aeson (Value)
|
||||
import Data.Aeson.Lens (key, _Integral)
|
||||
import qualified Data.Text as T
|
||||
import GHC.Generics (Generic)
|
||||
import Data.Serialize (Serialize)
|
||||
import HomeAssistant.Controller.Entity (entityChangeEvent', entityBool)
|
||||
import HomeAssistant.Controller.Effect (HASS)
|
||||
import Prelude hiding ((.))
|
||||
|
||||
lightBrightnessEvent :: T.Text -> HASS (Event Value) (Event Int)
|
||||
lightBrightnessEvent entityId =
|
||||
entityChangeEvent' entityId
|
||||
>>| arr (maybe (Left ()) Right . eventBrightness)
|
||||
>>> AFRP.toEvent
|
||||
where
|
||||
eventBrightness v = v ^? key "event" . key "variables" . key "trigger" . key "to_state" . key "attributes" . key "brightness" . _Integral
|
||||
|
||||
lightTemperatureEvent :: T.Text -> HASS (Event Value) (Event Int)
|
||||
lightTemperatureEvent entityId =
|
||||
entityChangeEvent' entityId
|
||||
>>| arr (maybe (Left ()) Right . eventTemperature)
|
||||
>>> AFRP.toEvent
|
||||
where
|
||||
eventTemperature v = v ^? key "event" . key "variables" . key "trigger" . key "to_state" . key "attributes" . key "color_temp_kelvin" . _Integral
|
||||
|
||||
data LightSnapshot = LightSnapshot
|
||||
{ observedOn :: Bool
|
||||
, observedBrightness :: Int
|
||||
, observedTemperature :: Int
|
||||
}
|
||||
deriving (Show, Generic, Eq)
|
||||
instance Serialize LightSnapshot
|
||||
|
||||
observedLight :: T.Text -> HASS (Event Value) LightSnapshot
|
||||
observedLight entityId = proc ev -> do
|
||||
e <- hold False . entityBool entityId -< ev
|
||||
b <- hold 0 . lightBrightnessEvent entityId -< ev
|
||||
t <- hold 0 . lightTemperatureEvent entityId -< ev
|
||||
returnA -< LightSnapshot e b t
|
||||
Reference in new issue
Block a user