101 lines
3.5 KiB
Haskell
101 lines
3.5 KiB
Haskell
{-# LANGUAGE OverloadedStrings #-}
|
|
{-# LANGUAGE Arrows #-}
|
|
module HomeAssistant.Controller.Livingroom where
|
|
|
|
import HomeAssistant.Controller (HASS, Presence (..), Target (..), presence, callServiceDyn, light, Light (..), traceEvent, callService, activateScene)
|
|
import qualified AFRP
|
|
import Control.Arrow ((>>>), Arrow (..), returnA)
|
|
import Data.Aeson (Value)
|
|
import Prelude hiding ((.))
|
|
import Control.Category ((.))
|
|
import Data.Time (LocalTime(..), toGregorian, TimeOfDay (..))
|
|
|
|
data Lights = LightsOn | LightsOff
|
|
deriving (Show)
|
|
|
|
livingroomPresence :: HASS (AFRP.Event Value) Presence
|
|
livingroomPresence = presence "binary_sensor.occupancy_olohuone_derived" >>> AFRP.hold Unoccupied
|
|
|
|
eventLights :: HASS Presence (AFRP.Event Lights)
|
|
eventLights = AFRP.changes >>> arr (fmap presenceLights)
|
|
where
|
|
presenceLights Occupied = LightsOn
|
|
presenceLights Unoccupied = LightsOff
|
|
|
|
|
|
-- There's a small race condition / corner case bug in the og implementation
|
|
-- I have a couple of lights in the Livingroom
|
|
--
|
|
-- - Ceiling ilght
|
|
-- - "Sofa light", a small reading nook light
|
|
-- - A few strong lights at a plant corner
|
|
--
|
|
-- The plant corner lights are not started by the automation. They are started by a separate schedule
|
|
-- But, they are turned off by the automation
|
|
-- So their status gets messed if their schedule turns on while there is nobody in the room
|
|
--
|
|
--
|
|
-- With that in mind, I'll be explicitly controlling the two lights, without any scene shenanigans
|
|
|
|
|
|
lights :: [Target]
|
|
lights = [EntityId "light.livingroom_ceiling", EntityId "light.livingroom_sofa"]
|
|
|
|
livingroomPresenceController :: HASS (AFRP.Event Value) ()
|
|
livingroomPresenceController = proc x -> do
|
|
ev <- eventLights . livingroomPresence -< x
|
|
traceEvent -< ev
|
|
case ev of
|
|
AFRP.Event LightsOn -> callServiceDyn (light lights) -< On Nothing
|
|
AFRP.Event LightsOff -> callServiceDyn (light lights) -< Off
|
|
_ -> returnA -< ()
|
|
returnA -< ()
|
|
|
|
data Season = Summer | Fall | Winter | Spring
|
|
deriving Show
|
|
|
|
|
|
season :: HASS a Season
|
|
season = AFRP.currentTime >>> arr toSeason
|
|
where
|
|
toSeason t =
|
|
case toGregorian (localDay t) of
|
|
(_, m, _)
|
|
| m >= 12 || m <= 2 -> Winter
|
|
| m <= 5 -> Spring
|
|
| m <= 8 -> Summer
|
|
| otherwise -> Fall
|
|
|
|
tod :: HASS a TimeOfDay
|
|
tod = AFRP.currentTime >>> arr localTimeOfDay
|
|
|
|
data PlantLightMode = Growth | Ambience
|
|
deriving Show
|
|
|
|
plantLightMode :: HASS (Season, TimeOfDay) (AFRP.Event PlantLightMode)
|
|
plantLightMode =
|
|
(lightMode &&& ambienceMode) >>> arr (uncurry AFRP.lMerge)
|
|
where
|
|
lightMode = arr (uncurry lightWanted) >>> AFRP.edge >>> arr (AFRP.tag Growth)
|
|
ambienceMode = arr (uncurry ambienceWanted) >>> AFRP.edge >>> arr (AFRP.tag Ambience)
|
|
-- Full brightness during daytime only non-summer
|
|
lightWanted :: Season -> TimeOfDay -> Bool
|
|
lightWanted Summer _ = False
|
|
lightWanted _ TimeOfDay{todHour=10,todMin=00} = True
|
|
lightWanted _ _ = False
|
|
-- Ambience mode is always
|
|
ambienceWanted :: Season -> TimeOfDay -> Bool
|
|
ambienceWanted _ TimeOfDay{todHour=20,todMin=0} = True
|
|
ambienceWanted _ _ = False
|
|
|
|
livingroomPlantLights :: HASS (AFRP.Event a) ()
|
|
livingroomPlantLights = (season &&& tod)
|
|
>>> plantLightMode
|
|
>>> setLights
|
|
where
|
|
setLights = proc mode -> do
|
|
case mode of
|
|
AFRP.Event Growth -> callService (activateScene "scene.olohuoneen_kasvivalo") -< ()
|
|
AFRP.Event Ambience -> callService (activateScene "scene.kasvivalo_iltatila") -< ()
|
|
_ -> returnA -< ()
|